YARA-L rules: 0r

// Copyright 2025 Google LLC. Licensed under Apache-2.0.

rule entra_id_devicecode_phishing_attack {

  meta:
    author = "Bastradamus"
    description = "Detects strong indicators of a successful device code phishing attack."
    severity = "High"
    priority = "High"
    rule_id = "mr_8b29e3d1-5c42-4f91-9aef-b673ad89f0e4"
    rule_name = "Microsoft Entra ID Device code phishing attack"
    type = "alert"
    data_source = "Workspace Activity, azure ad"
    reference = "https://systemweakness.com/detecting-device-code-phishing-in-google-security-operations-9bf1c282cff0"
    mitre_attack_tactic = "Initial Access"
    mitre_attack_technique = "Phishing"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1566/"

  events:
    $email.network.email.to = $user
    $email.metadata.vendor_name = "Google Workspace"
    $email.metadata.product_name = "gmail" nocase
    $email.about.url = /microsoft.com\/devicelogin/ or
    $email.about.url = /oauth2\/deviceauth/
    //user clicks the device code phish URL.
    $email.about.labels.value = /71|9/

    $entra.metadata.vendor_name = "Microsoft"
    $entra.metadata.product_name = "Azure AD"
    //Entra error code 50199: The user was asked to confirm that this app is the application they intended to sign into.
    $entra.security_result.rule_id = /^(0|50199)$/

    //join
    $email.network.email.to = $entra.target.user.userid

  match:
    //Time window based on the fact that the device code expires within 15 minutes. Added an extra 60 seconds.
    $user over 16m

  outcome:
    $mitre_attack_tactic = array_distinct("Initial Access")
    $mitre_attack_technique = array_distinct("Phishing")
    $mitre_attack_technique_id = array_distinct("T1566")
    $target_user_distinct_count = count_distinct($user)
    $target_user_count = count($user)
    $principal_ip = array_distinct($email.principal.ip)
    $sender_from = array_distinct($email.principal.network.email.from)
    $recipient = array_distinct($email.network.email.to)

  condition:
    $email and $entra
}

// Copyright 2024 Google LLC. Licensed under Apache-2.0.

rule onelogin_multiple_users_assumed {

  meta:
    author = "Google Cloud Security"
    description = "Detects when a user assumes multiple user accounts."
    rule_id = "mr_20b98df8-72a3-4163-8654-b66e4192d744"
    rule_name = "OneLogin Multiple Users Assumed"
    reference = "https://onelogin.service-now.com/kb_view_customer.do?sysparm_article=KB0010594"
    mitre_attack_tactic = "Lateral Movement"
    mitre_attack_technique = "Use Alternate Authentication Material"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1550/"
    mitre_attack_version = "v15.1"
    type = "Alert"
    data_source = "OneLogin"
    severity = "Low"
    priority = "Low"

  events:
     $assume.metadata.event_type = "USER_RESOURCE_ACCESS"
     $assume.metadata.product_name = "ONELOGIN_SSO"
     $assume.metadata.vendor_name = "ONELOGIN"
     $assume.metadata.product_event_type = "3" //a user assumed another user
     $assume.principal.user.userid = $actor_user

  match:
    $actor_user over 1h

  outcome:
    $risk_score = max(35)
    $mitre_attack_tactic = "Lateral Movement"
    $mitre_attack_technique = "Use Alternate Authentication Material"
    $assume_reason = array_distinct($assume.metadata.description)
    $principal_user_userid = array_distinct($assume.principal.user.userid)
    $principal_user_user_display_name = array_distinct($assume.principal.user.user_display_name)
    $principal_ip = array_distinct($assume.principal.ip)
    $principal_ip_country = array_distinct($assume.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($assume.principal.ip_geo_artifact.location.state)
    $target_user_userid = array_distinct($assume.target.user.userid)
    $dc_target_user_userid = count_distinct($assume.target.user.userid)

  condition:
    $assume and $dc_target_user_userid > 3
}