YARA-L rules: 15

// Copyright 2023 Google LLC. Licensed under Apache-2.0.

rule aws_saml_identity_provider_changes {

  meta:
    author = "Google Cloud Security"
    description = "Detects create, update or delete events of a SAML provider in AWS."
    rule_id = "mr_2f36760a-241d-4ace-9142-db0ccf1992b7"
    rule_name = "AWS SAML Identity Provider Changes"
    mitre_attack_tactic = "Defense Evasion, Persistence, Privilege Escalation, Initial Access"
    mitre_attack_technique = "Valid Accounts"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1078/"
    mitre_attack_version = "v13.1"
    type = "Alert"
    data_source = "AWS CloudTrail"
    platform = "AWS"
    severity = "Medium"
    priority = "Medium"

  events:
    $cloudtrail.metadata.vendor_name = "AMAZON"
    $cloudtrail.metadata.product_name = "AWS CloudTrail"
    (
      $cloudtrail.metadata.product_event_type = "CreateSAMLProvider" or
      $cloudtrail.metadata.product_event_type = "UpdateSAMLProvider" or
      $cloudtrail.metadata.product_event_type = "DeleteSAMLProvider"
    )
    $cloudtrail.security_result.action = "ALLOW"

  outcome:
    $risk_score = max(50)
    $mitre_attack_tactic = "Defense Evasion, Persistence, Privilege Escalation, Initial Access"
    $mitre_attack_technique = "Valid Accounts"
    $mitre_attack_technique_id = "T1078"
    $event_count = count_distinct($cloudtrail.metadata.id)
    $network_http_user_agent = $cloudtrail.network.http.user_agent
    $principal_ip = array_distinct($cloudtrail.principal.ip)
    $principal_ip_country = array_distinct($cloudtrail.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($cloudtrail.principal.ip_geo_artifact.location.state)
    $principal_user_display_name = $cloudtrail.principal.user.user_display_name
    $recipient_aws_account_id = $cloudtrail.additional.fields["recipientAccountId"]
    $aws_region = $cloudtrail.principal.location.name
    $target_resource_name = $cloudtrail.target.resource.name
    $target_resource_product_object_id = $cloudtrail.target.resource.product_object_id

  condition:
    $cloudtrail
}

// Copyright 2026 Google LLC. Licensed under Apache-2.0.

rule sap_suspected_data_exfiltration {

  meta:
    author = "Google Cloud Security"
    description = "Detects high-volume data downloads (AUY) from SAP to a local frontend file, potentially indicating exfiltration."
    severity = "Medium"
    tactic = "TA0010"
    technique = "T1041"

  events:
    $e.metadata.product_name = "SAP security audit"

    $e.additional.fields["msg_1"] = "AUY"

    $user = $e.principal.user.userid

  match:
    $user over 5m

  outcome:
    $event_count = count($e.metadata.product_log_id)
    $report_used = array_distinct($e.principal.process.file.names)
    $file_paths = array_distinct($e.additional.fields["param3_1"])
    $total_bytes_approx = array_distinct($e.additional.fields["param1_1"])
    $terminal_ip = array_distinct($e.principal.ip)
    $system_id = array_distinct($e.target.application)

  condition:
    $e and $event_count >= 10
}

// Copyright 2023 Google LLC. Licensed under Apache-2.0.

rule whoami_execution {

  meta:
    author = "Google Cloud Security"
    description = "Detects the execution of whoami, which is often used by attackers after exploitation to establish what credentials they are logged in under"
    rule_id = "mr_4372a068-1411-449f-b572-dc2b9358b5f4"
    rule_name = "Whoami Execution"
    type = "hunt"
    data_source = "microsoft sysmon, microsoft windows events"
    tactic = "TA0007"
    technique = "T1033"
    platform = "Windows"
    severity = "Info"
    priority = "Info"

  events:
    $process.metadata.event_type = "PROCESS_LAUNCH"
    $process.target.process.command_line = "whoami"

  outcome:
    $risk_score = 10
    // added to populate alert graph with additional context
    $principal_hostname = $process.principal.hostname
    $principal_process_pid = $process.principal.process.pid
    $principal_process_command_line = $process.principal.process.command_line
    $principal_process_file_sha256 = $process.principal.process.file.sha256
    $principal_process_file_full_path = $process.principal.process.file.full_path
    $principal_process_product_specific_process_id = $process.principal.process.product_specific_process_id
    $principal_process_parent_process_product_specific_process_id = $process.principal.process.parent_process.product_specific_process_id
    $target_process_pid = $process.target.process.pid
    $target_process_command_line = $process.target.process.command_line
    $target_process_file_sha256 = $process.target.process.file.sha256
    $target_process_file_full_path = $process.target.process.file.full_path
    $target_process_product_specific_process_id = $process.target.process.product_specific_process_id
    $principal_user_userid = $process.principal.user.userid

  condition:
    $process
}