YARA-L rules: 1o

// Copyright 2023 Google LLC. Licensed under Apache-2.0.

rule google_workspace_application_added {

  meta:
    author = "Google Cloud Security"
    description = "Identifies when a Marketplace app is added in a Google Workspace organization. Installing certain apps may increase the organization's risk of data exfiltration/leakage and increase its attack surface."
    rule_id = "mr_bb4f5ff0-76b8-4b08-8b1b-fcb81e5a10cc"
    rule_name = "Google Workspace Application Added"
    mitre_attack_tactic = "Persistence"
    mitre_attack_technique = ""
    mitre_attack_url = ""
    mitre_attack_version = "v13.1"
    type = "Alert"
    data_source = "Workspace Activity"
    severity = "High"
    priority = "High"

  events:
    $ws.metadata.vendor_name = "Google Workspace"
    $ws.metadata.product_name = "admin"
    $ws.metadata.product_event_type = "ADD_APPLICATION"

  outcome:
    $risk_score = max(75)
    $mitre_attack_tactic = "Persistence"
    $mitre_attack_technique = ""
    $mitre_attack_technique_id = ""
    $event_count = count_distinct($ws.metadata.id)
    $principal_ip = array_distinct($ws.principal.ip)
    $principal_country = array_distinct($ws.principal.ip_geo_artifact.location.country_or_region)
    $principal_state = array_distinct($ws.principal.ip_geo_artifact.location.state)
    $principal_user_emails = array_distinct($ws.principal.user.email_addresses)
    $principal_user_id = array_distinct($ws.principal.user.userid)
    $target_application = $ws.target.application
    $application_enabled = $ws.target.labels["application_enabled"]
    $application_id = $ws.target.resource.name

  condition:
    $ws
}

// Copyright 2025 Google LLC. Licensed under Apache-2.0.

rule ms_graph_application_endpoint_requests {

  meta:
    author = "Google Cloud Security"
    description = "Identify the use of the application API call to collect a listing of applications in Entra ID. This can be chatty due to other commands calling this single API."
    rule_id = "mr_0936c89c-4579-4e7c-a081-3129dd93a726"
    rule_name = "Hunt for application API calls in the Microsoft Graph"
    assumption = "Focus on PowerShell as part of the User agent or adding IP addresses or applications who call this endpoint should be added to focus this detection."
    type = "Hunt"
    data_source = "MS Graph Activity Logs"
    platform = "Azure"
    severity = "Low"
    priority = "Low"

  events:
    $api.metadata.event_type = "NETWORK_HTTP"
    $api.metadata.product_event_type = "Microsoft Graph Activity"
    $api.target.url = "https://graph.microsoft.com/v1.0/applications" nocase
    //Can be tuned for specific User Agent strings being used
    //$api.network.http.user_agent = /PowerShell/ nocase
    //May want to filter out IP addresses of admin consoles
    //$api.principal.ip != "10.10.10.10"
    $api.network.http.method = "GET"
    $api.network.http.response_code = 200
    $api.principal.ip = $ip
    $api.network.session_id = $session

  match:
    $ip, $session over 5m

  outcome:
    $risk_score = 35
    $event_count = count_distinct($api.metadata.id)
    $requesting_user_guid = array_distinct($api.principal.user.userid)
    $requesting_ip = array_distinct($api.principal.ip)
    $user_agent = array_distinct($api.network.http.user_agent)
    $location = array_distinct($api.principal.location.name)
    $target_application_id_guid = array_distinct($api.target.resource.product_object_id)
    $session_id = array_distinct($api.network.session_id)
    $target_url = array_distinct($api.target.url)

  condition:
    $api
}