YARA-L rules: 2v

// Copyright 2023 Google LLC. Licensed under Apache-2.0.

rule aws_s3_public_access_block_removed {
  meta:
    author = "Google Cloud Security"
    description = "Detect when the S3 Public Access Block configuration has been removed from a bucket or an account."
    rule_id = "mr_07638aec-6719-467b-9fee-8de4993087fa"
    rule_name = "AWS S3 Public Access Block Removed"
    mitre_attack_tactic = "Defense Evasion"
    mitre_attack_technique = "Impair Defenses"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1562/"
    mitre_attack_version = "v13.1"
    type = "Alert"
    data_source = "AWS CloudTrail"
    platform = "AWS"
    severity = "High"
    priority = "High"

  events:
    $cloudtrail.metadata.vendor_name = "AMAZON"
    $cloudtrail.metadata.product_name = "AWS CloudTrail"
    (
      $cloudtrail.metadata.product_event_type = "DeleteAccountPublicAccessBlock" or
      $cloudtrail.metadata.product_event_type = "DeleteBucketPublicAccessBlock" or
      (
        (
          $cloudtrail.metadata.product_event_type = "PutBucketPublicAccessBlock" or
          $cloudtrail.metadata.product_event_type = "PutAccountPublicAccessBlock"
        )
        and
        (
          $cloudtrail.target.resource.attribute.labels["RestrictPublicBuckets"] = "true" or
          $cloudtrail.target.resource.attribute.labels["BlockPublicPolicy"] = "true" or
          $cloudtrail.target.resource.attribute.labels["BlockPublicAcls"] = "true" or
          $cloudtrail.target.resource.attribute.labels["IgnorePublicAcls"] = "true"
        )
      )
    )
    $cloudtrail.security_result.action = "ALLOW"
    $cloudtrail.principal.user.userid = $user_id

  match:
    $user_id over 1h

  outcome:
    $risk_score = max(75)
    $mitre_attack_tactic = "Defense Evasion"
    $mitre_attack_technique = "Impair Defenses"
    $mitre_attack_technique_id = "T1562"
    $event_count = count_distinct($cloudtrail.metadata.id)
    $network_http_user_agent = array_distinct($cloudtrail.network.http.user_agent)
    $principal_ip = array_distinct($cloudtrail.principal.ip)
    $principal_ip_country = array_distinct($cloudtrail.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($cloudtrail.principal.ip_geo_artifact.location.state)
    $principal_user_display_name = array_distinct($cloudtrail.principal.user.user_display_name)
    $recipient_aws_account_id = array_distinct($cloudtrail.additional.fields["recipientAccountId"])
    $aws_region = array_distinct($cloudtrail.principal.location.name)
    $target_resource_name = array_distinct($cloudtrail.target.resource.name)
    $target_resource_product_object_id = array_distinct($cloudtrail.target.resource.product_object_id)

  condition:
    $cloudtrail
}

// Copyright 2025 Google LLC. Licensed under Apache-2.0.

rule ms_graph_failed_file_downloads_multiple_attempts {

  meta:
    author = "Google Cloud Security"
    description = "This detects when a 401 Unauthorized status is received on multiple attempts of the same file when attempting to download from OneDrive and may indicate a permissions issue for the user."
    rule_id = "mr_1117b547-0f30-444e-b10e-c9cfdf00f1f5"
    rule_name = "Multiple failed file downloads from OneDrive observed in the Microsoft Graph API"
    type = "alert"
    data_source = "MS Graph Activity Logs"
    platform = "Azure"
    severity = "Low"
    priority = "Low"

  events:
    $api.metadata.event_type = "NETWORK_HTTP"
    $api.metadata.product_event_type = "Microsoft Graph Activity"
    re.regex($api.target.url, `^https://graph\.microsoft\.com/v1\.0/drives/.*/content$`) nocase
    //Can be tuned for specific User Agent strings being used - by default GraphRunner does not forge the UA for this action
    //$api.network.http.user_agent = /PowerShell/ nocase
    $api.network.http.method = "GET"
    $api.network.http.response_code = 401
    $api.principal.ip = $ip
    $api.network.session_id = $session
    $api.target.url = $url

  match:
    $ip, $session, $url over 15m

  outcome:
    $risk_score = 35
    $event_count = count_distinct($api.metadata.id)
    $doc_count = count_distinct($api.target.url)
    $requesting_user_guid = array_distinct($api.principal.user.userid)
    $requesting_ip = array_distinct($api.principal.ip)
    $user_agent = array_distinct($api.network.http.user_agent)
    $location = array_distinct($api.principal.location.name)
    $target_application_id_guid = array_distinct($api.target.resource.product_object_id)
    $session_id = array_distinct($api.network.session_id)
    $target_url = array_distinct($api.target.url)

  condition:
    //Tune to the desired threshold
    #api > 2
}

// Copyright 2025 Google LLC. Licensed under Apache-2.0.

rule process_memory_dump_via_rdrleakdiag {

  meta:
    author = "Cedric MAURUGEON, Florian Roth (Nextron Systems), Swachchhanda Shrawan Poudel, Nasreddine Bencherchali (Nextron Systems)"
    description = "Detects the use of the Microsoft Windows Resource Leak Diagnostic tool rdrleakdiag.exe to dump process memory"
    reference = "https://github.com/SigmaHQ/sigma/blob/master/rules/windows/process_creation/proc_creation_win_rdrleakdiag_process_dumping.yml"
    license = "https://github.com/SigmaHQ/Detection-Rule-License/blob/main/LICENSE.Detection.Rules.md"
    rule_name = "Process Memory Dump via RdrLeakDiag.exe"
    sigma_uuid = "edadb1e5-5919-4e4c-8462-a9e643b02c4b"
    sigma_status = "test"
    rule_id = "mr_89eca7b6-5b7e-4bd1-978e-156bd00f5324"
    tactic = "TA0006"
    technique = "T1003.001"
    type = "Detection"
    data_source = "Windows Event Logs"
    platform = "Windows"
    severity = "High"
    priority = "High"
    false_positives = "Unlikely"

  events:
    $process.metadata.event_type = "PROCESS_LAUNCH"
    (
        re.regex($process.target.process.file.full_path, `rdrleakdiag\.exe$`) nocase or
        $process.src.process.file.full_path = "RdrLeakDiag.exe" nocase
    )
    re.regex($process.target.process.command_line, `(/|full)memdmp`) nocase
    re.regex($process.target.process.command_line, `/(o|p)`) nocase

    $process.principal.hostname = $hostname

  match:
    $hostname over 5m

  outcome:
    //example usage of specifying test user and hostname to adjust risk score
    $risk_score = max(if($process.principal.user.userid = "user" and $process.principal.hostname = "hostname", 0, 15))
    $principal_process_pid = array_distinct($process.principal.process.pid)
    $principal_process_command_line = array_distinct($process.principal.process.command_line)
    $principal_process_file_sha256 = array_distinct($process.principal.process.file.sha256)
    $principal_process_file_full_path = array_distinct($process.principal.process.file.full_path)
    $principal_process_product_specfic_process_id = array_distinct($process.principal.process.product_specific_process_id)
    $principal_process_parent_process_product_specfic_process_id = array_distinct($process.principal.process.parent_process.product_specific_process_id)
    $target_process_pid = array_distinct($process.target.process.pid)
    $target_process_command_line = array_distinct($process.target.process.command_line)
    $target_process_file_sha256 = array_distinct($process.target.process.file.sha256)
    $target_process_file_full_path = array_distinct($process.target.process.file.full_path)
    $target_process_product_specfic_process_id = array_distinct($process.target.process.product_specific_process_id)
    $principal_user_userid = array_distinct($process.principal.user.userid)
    $log_type = array_distinct(strings.concat($process.metadata.log_type,"/",$process.metadata.product_event_type))

  condition:
    $process
}

// Copyright 2025 Google LLC. Licensed under Apache-2.0.

rule suspicious_file_downloaded_from_file_sharing_website_via_certutil_exe {

  meta:
    author = "Nasreddine Bencherchali (Nextron Systems)"
    description = "Detects the execution of certutil with certain flags that allow the utility to download files from file-sharing websites"
    reference = "https://github.com/SigmaHQ/sigma/blob/master/rules/windows/process_creation/proc_creation_win_certutil_download_file_sharing_domains.yml"
    license = "https://github.com/SigmaHQ/Detection-Rule-License/blob/main/LICENSE.Detection.Rules.md"
    rule_name = "Suspicious File Downloaded From File-Sharing Website Via Certutil.EXE"
    sigma_uuid = "42a5f1e7-9603-4f6d-97ae-3f37d130d794"
    sigma_status = "experimental"
    rule_id = "mr_f61b63c4-96f0-4c2c-9f63-2e1dc16ddcf8"
    tactic = "TA0005"
    technique = "T1027"
    type = "Detection"
    data_source = "Sysmon"
    platform = "Windows"
    severity = "High"
    priority = "High"
    false_positives = "Unknown"

  events:
    $process.metadata.event_type = "PROCESS_LAUNCH"
    (
        re.regex($process.target.process.file.full_path, `\\certutil\.exe$`) nocase or
        $process.src.process.file.full_path = "certutil.exe" nocase
    )
    (
        strings.contains(strings.to_lower($process.target.process.command_line), "urlcache ") or
        strings.contains(strings.to_lower($process.target.process.command_line), "verifyctl ")
    )
    (
        strings.contains(strings.to_lower($process.target.process.command_line), ".githubusercontent.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "anonfiles.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "cdn.discordapp.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "ddns.net") or
        strings.contains(strings.to_lower($process.target.process.command_line), "dl.dropboxusercontent.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "ghostbin.co") or
        strings.contains(strings.to_lower($process.target.process.command_line), "glitch.me") or
        strings.contains(strings.to_lower($process.target.process.command_line), "gofile.io") or
        strings.contains(strings.to_lower($process.target.process.command_line), "hastebin.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "mediafire.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "mega.nz") or
        strings.contains(strings.to_lower($process.target.process.command_line), "onrender.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "pages.dev") or
        strings.contains(strings.to_lower($process.target.process.command_line), "paste.ee") or
        strings.contains(strings.to_lower($process.target.process.command_line), "pastebin.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "pastebin.pl") or
        strings.contains(strings.to_lower($process.target.process.command_line), "pastetext.net") or
        strings.contains(strings.to_lower($process.target.process.command_line), "privatlab.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "privatlab.net") or
        strings.contains(strings.to_lower($process.target.process.command_line), "send.exploit.in") or
        strings.contains(strings.to_lower($process.target.process.command_line), "sendspace.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "storage.googleapis.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "storjshare.io") or
        strings.contains(strings.to_lower($process.target.process.command_line), "supabase.co") or
        strings.contains(strings.to_lower($process.target.process.command_line), "temp.sh") or
        strings.contains(strings.to_lower($process.target.process.command_line), "transfer.sh") or
        strings.contains(strings.to_lower($process.target.process.command_line), "trycloudflare.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "ufile.io") or
        strings.contains(strings.to_lower($process.target.process.command_line), "w3spaces.com") or
        strings.contains(strings.to_lower($process.target.process.command_line), "workers.dev")
    )
    $process.principal.hostname = $hostname

  match:
    $hostname over 5m

  outcome:
      //example usage of specifying test user and hostname to adjust risk score
      $risk_score = max(if($process.principal.user.userid = "user" and $process.principal.hostname = "hostname", 0, 15))
      $principal_process_pid = array_distinct($process.principal.process.pid)
      $principal_process_command_line = array_distinct($process.principal.process.command_line)
      $principal_process_file_sha256 = array_distinct($process.principal.process.file.sha256)
      $principal_process_file_full_path = array_distinct($process.principal.process.file.full_path)
      $principal_process_product_specfic_process_id = array_distinct($process.principal.process.product_specific_process_id)
      $principal_process_parent_process_product_specfic_process_id = array_distinct($process.principal.process.parent_process.product_specific_process_id)
      $target_process_pid = array_distinct($process.target.process.pid)
      $target_process_command_line = array_distinct($process.target.process.command_line)
      $target_process_file_sha256 = array_distinct($process.target.process.file.sha256)
      $target_process_file_full_path = array_distinct($process.target.process.file.full_path)
      $target_process_product_specfic_process_id = array_distinct($process.target.process.product_specific_process_id)
      $principal_user_userid = array_distinct($process.principal.user.userid)
      $log_type = array_distinct(strings.concat($process.metadata.log_type,"/",$process.metadata.product_event_type))

  condition:
    $process
}