AWS API Gateway Keys Accessed

Severity: low
Type: Alert
Time window: 1h
Match by: ip
Author: Google Cloud Security
Source: github.com/chronicle/detection-rules

Detects when AWS API Gateway keys are accessed.

MITRE ATT&CK coverage

Tactic	Techniques
Credential Access	`T1555` Credentials from Password Stores

Telemetry coverage

Platform	Record / event type
AWS	CloudTrail event `GetApiKey`: Retrieves the details of a specific API key, including its value, associated usage plans, and enabled status.
AWS	CloudTrail event `GetApiKeys`: Lists all API keys in the account, optionally filtered by usage plan or name prefix, and optionally including key values.

Rule body

// Copyright 2024 Google LLC. Licensed under Apache-2.0.

rule aws_api_gateway_get_keys {

  meta:
    author = "Google Cloud Security"
    description = "Detects when AWS API Gateway keys are accessed."
    rule_id = "mr_1d8ffb2e-ca26-4f8f-8ca1-3dd4694776f5"
    rule_name = "AWS API Gateway Keys Accessed"
    mitre_attack_tactic = "Credential Access"
    mitre_attack_technique = "Credentials from Password Stores"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1555/"
    mitre_attack_version = "v15.1"
    type = "Alert"
    data_source = "AWS CloudTrail"
    platform = "AWS"
    severity = "Low"
    priority = "Low"

  events:
    $cloudtrail.metadata.vendor_name = "AMAZON"
    $cloudtrail.metadata.product_name = "AWS CloudTrail"
    (
        ($cloudtrail.metadata.product_event_type = "GetApiKey" and $cloudtrail.target.resource.attribute.labels["requestParameters.includeValue"] = "true") or
        ($cloudtrail.metadata.product_event_type = "GetApiKeys" and $cloudtrail.target.resource.attribute.labels["requestParameters.includeValues"] = "true")
    )
    $cloudtrail.security_result.action = "ALLOW"
    $cloudtrail.principal.ip = $ip

  match:
    $ip over 1h

  outcome:
    $risk_score = max(35)
    $mitre_attack_tactic = "Credential Access"
    $mitre_attack_technique = "Credentials from Password Stores"
    $mitre_attack_technique_id = "T1555"
    $event_count = count_distinct($cloudtrail.metadata.id)
    $network_http_user_agent = array_distinct($cloudtrail.network.http.user_agent)
    $principal_ip = array_distinct($cloudtrail.principal.ip)
    $principal_ip_country = array_distinct($cloudtrail.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($cloudtrail.principal.ip_geo_artifact.location.state)
    $principal_user_display_name = array_distinct($cloudtrail.principal.user.user_display_name)
    $recipient_aws_account_id = array_distinct($cloudtrail.additional.fields["recipientAccountId"])
    $aws_region = array_distinct($cloudtrail.principal.location.name)
    $target_api_key = array_distinct($cloudtrail.target.resource.attribute.labels["requestParameters.apiKey"])
    $accessed_via_console = array_distinct($cloudtrail.target.resource.attribute.labels["sessionCredentialFromConsole"])

  condition:
    $cloudtrail
}

YARA-L rule structure

Condition

Fires when at least one $cloudtrail event in the 1h window.

Events

`$cloudtrail`

metadata.product_event_type = "GetApiKey"
target.resource.attribute.labels["requestParameters.includeValue"] = "true"
metadata.product_event_type = "GetApiKeys"
target.resource.attribute.labels["requestParameters.includeValues"] = "true"
security_result.action = "ALLOW"

Match and correlation

Match key: $ip (principal.ip)
Within: 1h

Outcome

Outcome variables add context to a detection. When the rule generates an alert, $risk_score is displayed with it.

Field	Expression
`risk_score`	`max(35)`
`event_count`	`count_distinct($cloudtrail.metadata.id)`
`network_http_user_agent`	`array_distinct($cloudtrail.network.http.user_agent)`
`principal_ip`	`array_distinct($cloudtrail.principal.ip)`
`principal_ip_country`	`array_distinct($cloudtrail.principal.ip_geo_artifact.location.country_or_region)`
`principal_ip_state`	`array_distinct($cloudtrail.principal.ip_geo_artifact.location.state)`
`principal_user_display_name`	`array_distinct($cloudtrail.principal.user.user_display_name)`
`recipient_aws_account_id`	`array_distinct($cloudtrail.additional.fields["recipientAccountId"])`
`aws_region`	`array_distinct($cloudtrail.principal.location.name)`
`target_api_key`	`array_distinct($cloudtrail.target.resource.attribute.labels["requestParameters.apiKey"])`
`accessed_via_console`	`array_distinct($cloudtrail.target.resource.attribute.labels["sessionCredentialFromConsole"])`