AWS IAM Activity From EC2 Instance

Severity: high
Type: Alert
Time window: 1h
Match by: ip
Author: Google Cloud Security
Source: github.com/chronicle/detection-rules

Detect AWS IAM activities made by AWS EC2 instances to retain access or escalate privileges.

MITRE ATT&CK coverage

Tactic	Techniques
Persistence	`T1098` Account Manipulation

Telemetry coverage

Platform	Record / event type
AWS	CloudTrail event `AttachGroupPolicy`: Attaches a managed IAM policy to an IAM group, granting the group's users the permissions defined in the policy.
AWS	CloudTrail event `AttachRolePolicy`: Attaches a managed IAM policy to an IAM role, adding the policy's permissions to the role.
AWS	CloudTrail event `AttachUserPolicy`: Attaches a managed IAM policy directly to an IAM user, granting that user the permissions defined in the policy.
AWS	CloudTrail event `CreateAccessKey`: Creates a new AWS access key pair (access key ID and secret access key) for the specified IAM user.
AWS	CloudTrail event `CreateLoginProfile`: Creates a password for the specified IAM user, enabling console sign-in for that user.
AWS	CloudTrail event `CreateRole`: Creates a new IAM role with a specified trust policy, defining which principals can assume the role.
AWS	CloudTrail event `UpdateLoginProfile`: Changes the password of the console login profile for the specified IAM user.

Rule body

// Copyright 2023 Google LLC. Licensed under Apache-2.0.

rule aws_iam_activity_from_ec2_instance {

  meta:
    author = "Google Cloud Security"
    description = "Detect AWS IAM activities made by AWS EC2 instances to retain access or escalate privileges."
    rule_id = "mr_60c7bb2f-2f02-4ac5-bbe0-ba8be871f3fb"
    rule_name = "AWS IAM Activity From EC2 Instance"
    mitre_attack_tactic = "Persistence"
    mitre_attack_technique = "Account Manipulation"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1098/"
    mitre_attack_version = "v13.1"
    type = "Alert"
    data_source = "AWS CloudTrail"
    platform = "AWS"
    severity = "High"
    priority = "High"

  events:
    $cloudtrail.metadata.vendor_name = "AMAZON"
    $cloudtrail.metadata.product_name = "AWS CloudTrail"
    $cloudtrail.target.application = "iam.amazonaws.com"
    (
    $cloudtrail.metadata.product_event_type = "CreateUser" or
    $cloudtrail.metadata.product_event_type = "AttachUserPolicy" or
    $cloudtrail.metadata.product_event_type = "CreateLoginProfile" or
    $cloudtrail.metadata.product_event_type = "UpdateLoginProfile" or
    $cloudtrail.metadata.product_event_type = "CreateAccessKey" or
    $cloudtrail.metadata.product_event_type = "CreateGroup" or
    $cloudtrail.metadata.product_event_type = "AttachGroupPolicy" or
    $cloudtrail.metadata.product_event_type = "CreateRole" or
    $cloudtrail.metadata.product_event_type = "AttachRolePolicy"
    )
    $cloudtrail.security_result.action = "ALLOW"
    $cloudtrail.principal.ip = $ip
    $cloudtrail.principal.resource.type = "AssumedRole"
    $cloudtrail.principal.user.userid = /\/i-.*$/ //regex to be improved
    re.capture($cloudtrail.principal.user.userid, ":assumed-role/.*/(.*)$") = $instanceId

  match:
    $ip over 1h

  outcome:
    $risk_score = max(35)
    $mitre_attack_tactic = "Persistence"
    $mitre_attack_technique = "Account Manipulation"
    $mitre_attack_technique_id = "T1098"
    $event_count = count_distinct($cloudtrail.metadata.id)
    $network_http_user_agent = array_distinct($cloudtrail.network.http.user_agent)
    $principal_ip = array_distinct($cloudtrail.principal.ip)
    $principal_ip_country = array_distinct($cloudtrail.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($cloudtrail.principal.ip_geo_artifact.location.state)
    $principal_user_display_name = array_distinct($cloudtrail.principal.user.user_display_name)
    $recipient_aws_account_id = array_distinct($cloudtrail.additional.fields["recipientAccountId"])
    $aws_region = array_distinct($cloudtrail.principal.location.name)
    $target_resource_name = array_distinct($cloudtrail.target.resource.name)
    $target_resource_product_object_id = array_distinct($cloudtrail.target.resource.product_object_id)
    $ec2_instance_id = array_distinct($instanceId)

  condition:
    $cloudtrail
}

YARA-L rule structure

Condition

Fires when at least one $cloudtrail event in the 1h window.

Events

`$cloudtrail`

target.application = "iam.amazonaws.com"
metadata.product_event_type is one of:
- CreateUser
- AttachUserPolicy
- CreateLoginProfile
- UpdateLoginProfile
- CreateAccessKey
- CreateGroup
- AttachGroupPolicy
- CreateRole
- AttachRolePolicy
security_result.action = "ALLOW"
principal.resource.type = "AssumedRole"
principal.user.userid matches "\/i-.*$"

Match and correlation

Match key: $ip (principal.ip)
Within: 1h

Outcome

Outcome variables add context to a detection. When the rule generates an alert, $risk_score is displayed with it.

Field	Expression
`risk_score`	`max(35)`
`event_count`	`count_distinct($cloudtrail.metadata.id)`
`network_http_user_agent`	`array_distinct($cloudtrail.network.http.user_agent)`
`principal_ip`	`array_distinct($cloudtrail.principal.ip)`
`principal_ip_country`	`array_distinct($cloudtrail.principal.ip_geo_artifact.location.country_or_region)`
`principal_ip_state`	`array_distinct($cloudtrail.principal.ip_geo_artifact.location.state)`
`principal_user_display_name`	`array_distinct($cloudtrail.principal.user.user_display_name)`
`recipient_aws_account_id`	`array_distinct($cloudtrail.additional.fields["recipientAccountId"])`
`aws_region`	`array_distinct($cloudtrail.principal.location.name)`
`target_resource_name`	`array_distinct($cloudtrail.target.resource.name)`
`target_resource_product_object_id`	`array_distinct($cloudtrail.target.resource.product_object_id)`
`ec2_instance_id`	`array_distinct($instanceId)`