AWS KMS Key Disabled Or Scheduled For Deletion

Severity: high
Type: Alert
Author: Google Cloud Security
Source: github.com/chronicle/detection-rules

Detect when a KMS (Key Management Service) key is disabled or scheduled for deletion.

MITRE ATT&CK coverage

Tactic	Techniques
Impact	`T1485` Data Destruction

Telemetry coverage

Platform	Record / event type
AWS	CloudTrail event `DisableKey`: Sets the status of a KMS key to disabled, preventing its use in cryptographic operations until it is re-enabled.
AWS	CloudTrail event `ScheduleKeyDeletion`: Schedules a KMS key for deletion after a waiting period of 7 to 30 days, after which the key and its material are permanently deleted.

Rule body

// Copyright 2023 Google LLC. Licensed under Apache-2.0.

rule aws_kms_key_disabled_or_scheduled_for_deletion {

  meta:
    author = "Google Cloud Security"
    description = "Detect when a KMS (Key Management Service) key is disabled or scheduled for deletion."
    rule_id = "mr_b1947fef-7b98-4c10-8303-d6c9c032d84e"
    rule_name = "AWS KMS Key Disabled Or Scheduled For Deletion"
    mitre_attack_tactic = "Impact"
    mitre_attack_technique = "Data Destruction"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1485/"
    mitre_attack_version = "v13.1"
    type = "Alert"
    data_source = "AWS CloudTrail"
    platform = "AWS"
    severity = "High"
    priority = "High"

  events:
    $cloudtrail.metadata.vendor_name = "AMAZON"
    $cloudtrail.metadata.product_name = "AWS CloudTrail"
    $cloudtrail.metadata.product_event_type = "DisableKey" or $cloudtrail.metadata.product_event_type = "ScheduleKeyDeletion"
    $cloudtrail.security_result.action = "ALLOW"

  outcome:
    $risk_score = max(75)
    $mitre_attack_tactic = "Impact"
    $mitre_attack_technique = "Data Destruction"
    $mitre_attack_technique_id = "T1485"
    $event_count = count_distinct($cloudtrail.metadata.id)
    $network_http_user_agent = $cloudtrail.network.http.user_agent
    $principal_ip = array_distinct($cloudtrail.principal.ip)
    $principal_ip_country = array_distinct($cloudtrail.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($cloudtrail.principal.ip_geo_artifact.location.state)
    $principal_user_display_name = $cloudtrail.principal.user.user_display_name
    $recipient_aws_account_id = $cloudtrail.additional.fields["recipientAccountId"]
    $aws_region = $cloudtrail.principal.location.name
    $target_resource_name = $cloudtrail.target.resource.name
    $target_resource_product_object_id = $cloudtrail.target.resource.product_object_id

  condition:
    $cloudtrail
}

YARA-L rule structure

Condition

Fires when at least one $cloudtrail event.

Events

`$cloudtrail`

metadata.product_event_type = "DisableKey" or "ScheduleKeyDeletion"
security_result.action = "ALLOW"

Outcome

Outcome variables add context to a detection. When the rule generates an alert, $risk_score is displayed with it.

Field	Expression
`risk_score`	`max(75)`
`event_count`	`count_distinct($cloudtrail.metadata.id)`
`network_http_user_agent`	`$cloudtrail.network.http.user_agent`
`principal_ip`	`array_distinct($cloudtrail.principal.ip)`
`principal_ip_country`	`array_distinct($cloudtrail.principal.ip_geo_artifact.location.country_or_region)`
`principal_ip_state`	`array_distinct($cloudtrail.principal.ip_geo_artifact.location.state)`
`principal_user_display_name`	`$cloudtrail.principal.user.user_display_name`
`recipient_aws_account_id`	`$cloudtrail.additional.fields["recipientAccountId"]`
`aws_region`	`$cloudtrail.principal.location.name`
`target_resource_name`	`$cloudtrail.target.resource.name`
`target_resource_product_object_id`	`$cloudtrail.target.resource.product_object_id`