AWS Lambda Update Function Code

Severity: low
Type: Alert
Time window: 1h
Match by: user_id
Author: Google Cloud Security
Source: github.com/chronicle/detection-rules

Detects an IAM user attempting to update/modify AWS lambda code.

MITRE ATT&CK coverage

Tactic	Techniques
Execution	`T1648` Serverless Execution

Telemetry coverage

Platform	Record / event type
AWS	CloudTrail event `UpdateFunctionCode`: Updates a Lambda function's code.

Rule body

// Copyright 2023 Google LLC. Licensed under Apache-2.0.

rule aws_lambda_update_function_code {

  meta:
    author = "Google Cloud Security"
    description = "Detects an IAM user attempting to update/modify AWS lambda code."
    rule_id = "mr_046e8bc7-2d48-4118-ae38-eb095a4333e3"
    rule_name = "AWS Lambda Update Function Code"
    mitre_attack_tactic = "Execution"
    mitre_attack_technique = "Serverless Execution"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1648/"
    mitre_attack_version = "v13.1"
    type = "Alert"
    data_source = "AWS CloudTrail"
    platform = "AWS"
    severity = "Low"
    priority = "Low"

  events:
    $cloudtrail.metadata.vendor_name = "AMAZON"
    $cloudtrail.metadata.product_name = "AWS CloudTrail"
    $cloudtrail.metadata.product_event_type = /UpdateFunctionCode/
    $cloudtrail.security_result.action = "ALLOW"
    $cloudtrail.principal.user.userid = $user_id

  match:
    $user_id over 1h

  outcome:
    $risk_score = max(35)
    $mitre_attack_tactic = "Execution"
    $mitre_attack_technique = "Serverless Execution"
    $mitre_attack_technique_id = "T1648"
    $event_count = count_distinct($cloudtrail.metadata.id)
    $network_http_user_agent = array_distinct($cloudtrail.network.http.user_agent)
    $principal_ip = array_distinct($cloudtrail.principal.ip)
    $principal_ip_country = array_distinct($cloudtrail.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($cloudtrail.principal.ip_geo_artifact.location.state)
    $principal_user_display_name = array_distinct($cloudtrail.principal.user.user_display_name)
    $recipient_aws_account_id = array_distinct($cloudtrail.additional.fields["recipientAccountId"])
    $aws_region = array_distinct($cloudtrail.principal.location.name)
    $target_resource_name = array_distinct($cloudtrail.target.resource.name)
    $target_resource_product_object_id = array_distinct($cloudtrail.target.resource.product_object_id)

  condition:
    $cloudtrail
}

YARA-L rule structure

Condition

Fires when at least one $cloudtrail event in the 1h window.

Events

`$cloudtrail`

metadata.product_event_type matches "UpdateFunctionCode"
security_result.action = "ALLOW"

Match and correlation

Match key: $user_id (principal.user.userid)
Within: 1h

Outcome

Outcome variables add context to a detection. When the rule generates an alert, $risk_score is displayed with it.

Field	Expression
`risk_score`	`max(35)`
`event_count`	`count_distinct($cloudtrail.metadata.id)`
`network_http_user_agent`	`array_distinct($cloudtrail.network.http.user_agent)`
`principal_ip`	`array_distinct($cloudtrail.principal.ip)`
`principal_ip_country`	`array_distinct($cloudtrail.principal.ip_geo_artifact.location.country_or_region)`
`principal_ip_state`	`array_distinct($cloudtrail.principal.ip_geo_artifact.location.state)`
`principal_user_display_name`	`array_distinct($cloudtrail.principal.user.user_display_name)`
`recipient_aws_account_id`	`array_distinct($cloudtrail.additional.fields["recipientAccountId"])`
`aws_region`	`array_distinct($cloudtrail.principal.location.name)`
`target_resource_name`	`array_distinct($cloudtrail.target.resource.name)`
`target_resource_product_object_id`	`array_distinct($cloudtrail.target.resource.product_object_id)`