AWS Successful Console Authentication From Multiple IPs

Severity: medium
Type: Alert
Time window: 5m
Match by: user_id
Author: Google Cloud Security
Source: github.com/chronicle/detection-rules

Detects when an AWS user successfully authenticating from more than one unique IP address within 5 minutes.

MITRE ATT&CK coverage

Tactic	Techniques
Resource Development	`T1586` Compromise Accounts

Telemetry coverage

Platform	Record / event type
AWS	CloudTrail event `ConsoleLogin`: Records an authentication attempt to the AWS Management Console, including whether it succeeded or failed.

Rule body

// Copyright 2023 Google LLC. Licensed under Apache-2.0.

rule aws_successful_console_authentication_from_multiple_ips {

  meta:
    author = "Google Cloud Security"
    description = "Detects when an AWS user successfully authenticating from more than one unique IP address within 5 minutes."
    rule_id = "mr_4a221c43-1059-4247-a7a6-69d8ce4dca2c"
    rule_name = "AWS Successful Console Authentication From Multiple IPs"
    mitre_attack_tactic = "Resource Development"
    mitre_attack_technique = "Compromise Accounts"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1586/"
    mitre_attack_version = "v13.1"
    type = "Alert"
    data_source = "AWS CloudTrail"
    platform = "AWS"
    severity = "Medium"
    priority = "Medium"

  events:
    $login.metadata.vendor_name = "AMAZON"
    $login.metadata.product_name = "AWS CloudTrail"
    $login.metadata.event_type = "USER_LOGIN"
    $login.metadata.product_event_type = "ConsoleLogin"
    $login.security_result.action = "ALLOW"
    $login.principal.ip = $ip
    $login.target.user.userid = $user_id

  match:
    $user_id over 5m

  outcome:
    $risk_score = max(
        // Unauthorized geographies
        if($login.principal.ip_geo_artifact.location.country_or_region = "Cuba", 40) +
        if($login.principal.ip_geo_artifact.location.country_or_region = "Iran", 40) +
        if($login.principal.ip_geo_artifact.location.country_or_region = "North Korea" , 40) +
        if($login.principal.ip_geo_artifact.location.country_or_region = "Russia", 40) +
        if($login.principal.ip_geo_artifact.location.country_or_region = "Syria", 40)
    )
    $mitre_attack_tactic = "Resource Development"
    $mitre_attack_technique = "Compromise Accounts"
    $mitre_attack_technique_id = "T1586"
    $event_count = count_distinct($login.metadata.id)
    $network_http_user_agent = array_distinct($login.network.http.user_agent)
    $principal_ip = array_distinct($login.principal.ip)
    $principal_ip_country = array_distinct($login.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($login.principal.ip_geo_artifact.location.state)
    $target_user_userid = array_distinct($login.target.user.userid)
    $is_mfa_used = array_distinct($login.extensions.auth.auth_details)
    $target_resource_name = array_distinct($login.target.resource.name)
    $target_resource_product_object_id = array_distinct($login.target.resource.product_object_id)

  condition:
    $login and #ip > 1
}

YARA-L rule structure

Condition

Fires when at least one $login event in the 5m window and $ip occurs more than 1 times in the 5m window.

Events

`$login` `USER_LOGIN`

metadata.product_event_type = "ConsoleLogin"
security_result.action = "ALLOW"

Match and correlation

Match key: $user_id (target.user.userid)
Within: 5m

Outcome

Outcome variables add context to a detection. When the rule generates an alert, $risk_score is displayed with it.

Field	Expression
`risk_score`	`max( if($login.principal.ip_geo_artifact.location.country_or_region = "Cuba", 40) + if($login.principal.ip_geo_artifact.location.country_or_region = "Iran", 40) + if($login.principal.ip_geo_artifact.location.country_or_region = "North Korea" , 40) + if($login.principal.ip_geo_artifact.location.country_or_region = "Russia", 40) + if($login.principal.ip_geo_artifact.location.country_or_region = "Syria", 40) )`
`event_count`	`count_distinct($login.metadata.id)`
`network_http_user_agent`	`array_distinct($login.network.http.user_agent)`
`principal_ip`	`array_distinct($login.principal.ip)`
`principal_ip_country`	`array_distinct($login.principal.ip_geo_artifact.location.country_or_region)`
`principal_ip_state`	`array_distinct($login.principal.ip_geo_artifact.location.state)`
`target_user_userid`	`array_distinct($login.target.user.userid)`
`is_mfa_used`	`array_distinct($login.extensions.auth.auth_details)`
`target_resource_name`	`array_distinct($login.target.resource.name)`
`target_resource_product_object_id`	`array_distinct($login.target.resource.product_object_id)`