Direct Autorun Keys Modification

/*
 * Copyright 2025 Google LLC
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

rule direct_autorun_keys_modification {

  meta:
    author = "Victor Sergeev, Daniil Yugoslavskiy, oscd.community"
    description = "Detects direct modification of autostart extensibility point (ASEP) in registry using reg.exe"
    reference = "https://github.com/SigmaHQ/sigma/blob/master/rules/windows/process_creation/proc_creation_win_reg_direct_asep_registry_keys_modification.yml"
    license = "https://github.com/SigmaHQ/Detection-Rule-License/blob/main/LICENSE.Detection.Rules.md"
    rule_name = "Direct Autorun Keys Modification"
    rule_id = "mr_b031bea5-d00b-43ae-a74c-b4df380262e8"
    sigma_uuid = "24357373-078f-44ed-9ac4-6d334a668a11"
    sigma_status = "test"
    tactic = "TA0003"
    technique = "T1547.001"
    type = "Detection"
    data_source = "Windows Event Logs"
    platform = "Windows"
    severity = "Medium"
    priority = "Medium"
    false_positives = "Legitimate software automatically sets up autorun keys for legitimate reasons"

  events:
    $process.metadata.event_type = "PROCESS_LAUNCH"
    re.regex($process.target.process.file.full_path, `\\reg\.exe$`) nocase
    strings.contains(strings.to_lower($process.target.process.command_line), "add")
    (
      strings.contains(strings.to_lower($process.target.process.command_line), "\\software\\microsoft\\windows\\currentversion\\run") or
      strings.contains(strings.to_lower($process.target.process.command_line), "\\software\\microsoft\\windows nt\\currentversion\\winlogon\\userinit") or
      strings.contains(strings.to_lower($process.target.process.command_line), "\\software\\microsoft\\windows nt\\currentversion\\winlogon\\shell") or
      strings.contains(strings.to_lower($process.target.process.command_line), "\\software\\microsoft\\windows nt\\currentversion\\windows") or
      strings.contains(strings.to_lower($process.target.process.command_line), "\\software\\microsoft\\windows\\currentversion\\explorer\\user shell folders") or
      strings.contains(strings.to_lower($process.target.process.command_line), "\\system\\currentcontrolset\\control\\safeboot\\alternateshell")
    )

    $process.principal.hostname = $hostname

  match:
    $hostname over 5m

  outcome:
    //example usage of specifying test user and hostname to adjust risk score
    $risk_score = max(if($process.principal.user.userid = "user" and $process.principal.hostname = "hostname", 0, 15))
    $principal_process_pid = array_distinct($process.principal.process.pid)
    $principal_process_command_line = array_distinct($process.principal.process.command_line)
    $principal_process_file_sha256 = array_distinct($process.principal.process.file.sha256)
    $principal_process_file_full_path = array_distinct($process.principal.process.file.full_path)
    $principal_process_product_specfic_process_id = array_distinct($process.principal.process.product_specific_process_id)
    $principal_process_parent_process_product_specfic_process_id = array_distinct($process.principal.process.parent_process.product_specific_process_id)
    $target_process_pid = array_distinct($process.target.process.pid)
    $target_process_command_line = array_distinct($process.target.process.command_line)
    $target_process_file_sha256 = array_distinct($process.target.process.file.sha256)
    $target_process_file_full_path = array_distinct($process.target.process.file.full_path)
    $target_process_product_specfic_process_id = array_distinct($process.target.process.product_specific_process_id)
    $principal_user_userid = array_distinct($process.principal.user.userid)
    $log_type = array_distinct(strings.concat($process.metadata.log_type,"/",$process.metadata.product_event_type))

  condition:
    $process
}