GCP BigQuery Datasets Opened To Public

Severity: high
Type: Alert
Author: Google Cloud Security
Source: github.com/chronicle/detection-rules

Detect when GCP BigQuery datasets are opened to public by adding allUsers or allAuthenticatedUsers to the access policy.

MITRE ATT&CK coverage

Tactic	Techniques
Defense Impairment	`T1685` Disable or Modify Tools

Telemetry coverage

Platform	Record / event type
GCP	google.iam.IAMPolicy.SetIamPolicy: Set IAM policy (IAMPolicy service)

Rule body

// Copyright 2024 Google LLC. Licensed under Apache-2.0.

 rule gcp_bigquery_datasets_opened_to_public {

  meta:
    author = "Google Cloud Security"
    description = "Detect when GCP BigQuery datasets are opened to public by adding allUsers or allAuthenticatedUsers to the access policy."
    rule_id = "mr_6d331411-347b-432e-ba52-ff78e4c66a3f"
    rule_name = "GCP BigQuery Datasets Opened To Public"
    mitre_attack_tactic = "Defense Evasion"
    mitre_attack_technique = "Impair Defenses"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1562/"
    mitre_attack_version = "v14.1"
    type = "Alert"
    data_source = "GCP Cloud Audit"
    platform = "GCP"
    severity = "High"
    priority = "High"

  events:
    $gcp.metadata.event_type = "USER_RESOURCE_UPDATE_PERMISSIONS"
    $gcp.metadata.log_type = "GCP_CLOUDAUDIT"
    $gcp.metadata.vendor_name = "Google Cloud Platform"
    $gcp.metadata.product_name = "BigQuery"
    $gcp.metadata.product_event_type = "google.iam.v1.IAMPolicy.SetIamPolicy"
    $gcp.target.application = "bigquery.googleapis.com"
    $gcp.security_result.action = "ALLOW"
    $gcp.target.resource.attribute.labels["dataset_change_binding_deltas_action"] = "ADD"
    $gcp.target.resource.attribute.labels["dataset_change_binding_deltas_role"] = /roles\/bigquery.*/
    $gcp.target.resource.attribute.labels["dataset_change_binding_deltas_member"] = /allUsers|allAuthenticatedUsers/
    $gcp.target.resource.resource_subtype = "bigquery_dataset"
    $gcp.target.resource.resource_type = "DATABASE"

  outcome:
    $risk_score = max(75)
    $mitre_attack_tactic = "Defense Evasion"
    $mitre_attack_technique = "Impair Defenses"
    $mitre_attack_technique_id = "T1562"
    $event_count = count_distinct($gcp.metadata.id)
    $network_http_user_agent = array_distinct($gcp.network.http.user_agent)
    $principal_ip = array_distinct($gcp.principal.ip)
    $principal_ip_country = array_distinct($gcp.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($gcp.principal.ip_geo_artifact.location.state)
    $principal_user_id = $gcp.principal.user.userid
    $principal_user_display_name = $gcp.principal.user.user_display_name
    $target_resource_name = $gcp.target.resource.name
    $event_name = $gcp.metadata.product_event_type

  condition:
    $gcp
}

YARA-L rule structure

Condition

Fires when at least one $gcp event.

Events

`$gcp` `USER_RESOURCE_UPDATE_PERMISSIONS`

metadata.log_type = "GCP_CLOUDAUDIT"
metadata.product_event_type = "google.iam.v1.IAMPolicy.SetIamPolicy"
target.application = "bigquery.googleapis.com"
security_result.action = "ALLOW"
target.resource.attribute.labels["dataset_change_binding_deltas_action"] = "ADD"
target.resource.attribute.labels["dataset_change_binding_deltas_role"] matches "roles\/bigquery.*"
target.resource.attribute.labels["dataset_change_binding_deltas_member"] matches "allUsers|allAuthenticatedUsers"
target.resource.resource_subtype = "bigquery_dataset"
target.resource.resource_type = "DATABASE"

Outcome

Outcome variables add context to a detection. When the rule generates an alert, $risk_score is displayed with it.

Field	Expression
`risk_score`	`max(75)`
`event_count`	`count_distinct($gcp.metadata.id)`
`network_http_user_agent`	`array_distinct($gcp.network.http.user_agent)`
`principal_ip`	`array_distinct($gcp.principal.ip)`
`principal_ip_country`	`array_distinct($gcp.principal.ip_geo_artifact.location.country_or_region)`
`principal_ip_state`	`array_distinct($gcp.principal.ip_geo_artifact.location.state)`
`principal_user_id`	`$gcp.principal.user.userid`
`principal_user_display_name`	`$gcp.principal.user.user_display_name`
`target_resource_name`	`$gcp.target.resource.name`
`event_name`	`$gcp.metadata.product_event_type`