GCP Multiple HMAC Keys Deleted

Severity: high
Type: Alert
Time window: 1h
Match by: user_id
Author: Google Cloud Security
Source: github.com/chronicle/detection-rules

Detect when multiple HMAC authentication keys are deleted from GCP Storage settings.

MITRE ATT&CK coverage

Tactic	Techniques
Impact	`T1531` Account Access Removal

Telemetry coverage

Platform	Record / event type
GCP	storage.hmacKeys.delete: Delete HMAC key

Rule body

// Copyright 2024 Google LLC. Licensed under Apache-2.0.

rule gcp_multiple_hmac_keys_deleted {

  meta:
    author = "Google Cloud Security"
    description = "Detect when multiple HMAC authentication keys are deleted from GCP Storage settings."
    rule_id = "mr_75b441f1-edde-4a33-bc12-06a92ccb9ba8"
    rule_name = "GCP Multiple HMAC Keys Deleted"
    mitre_attack_tactic = "Impact"
    mitre_attack_technique = "Account Access Removal"
    mitre_attack_url = "https://attack.mitre.org/techniques/T1531/"
    mitre_attack_version = "v14.1"
    type = "Alert"
    data_source = "GCP Cloud Audit"
    platform = "GCP"
    severity = "High"
    priority = "High"

  events:
    $gcp.metadata.event_type = "RESOURCE_DELETION"
    $gcp.metadata.log_type = "GCP_CLOUDAUDIT"
    $gcp.metadata.product_event_type = "storage.hmacKeys.delete"
    $gcp.target.application = "storage.googleapis.com"
    $gcp.target.user.userid = $user_id

  match:
    $user_id over 1h

  outcome:
    $risk_score = max(75)
    $mitre_attack_tactic = "Impact"
    $mitre_attack_technique = "Account Access Removal"
    $mitre_attack_technique_id = "T1531"
    $event_count = count_distinct($gcp.metadata.id)
    $network_http_user_agent = array_distinct($gcp.network.http.user_agent)
    $principal_ip = array_distinct($gcp.principal.ip)
    $principal_ip_country = array_distinct($gcp.principal.ip_geo_artifact.location.country_or_region)
    $principal_ip_state = array_distinct($gcp.principal.ip_geo_artifact.location.state)
    $principal_user_id = array_distinct($gcp.principal.user.userid)
    $principal_user_display_name = array_distinct($gcp.principal.user.user_display_name)
    $target_resource_name = array_distinct($gcp.target.resource.name)

  condition:
    #gcp >= 2
}

YARA-L rule structure

Condition

Fires when $gcp occurs at least 2 times in the 1h window.

Events

`$gcp` `RESOURCE_DELETION`

metadata.log_type = "GCP_CLOUDAUDIT"
metadata.product_event_type = "storage.hmacKeys.delete"
target.application = "storage.googleapis.com"

Match and correlation

Match key: $user_id (target.user.userid)
Within: 1h

Outcome

Outcome variables add context to a detection. When the rule generates an alert, $risk_score is displayed with it.

Field	Expression
`risk_score`	`max(75)`
`event_count`	`count_distinct($gcp.metadata.id)`
`network_http_user_agent`	`array_distinct($gcp.network.http.user_agent)`
`principal_ip`	`array_distinct($gcp.principal.ip)`
`principal_ip_country`	`array_distinct($gcp.principal.ip_geo_artifact.location.country_or_region)`
`principal_ip_state`	`array_distinct($gcp.principal.ip_geo_artifact.location.state)`
`principal_user_id`	`array_distinct($gcp.principal.user.userid)`
`principal_user_display_name`	`array_distinct($gcp.principal.user.user_display_name)`
`target_resource_name`	`array_distinct($gcp.target.resource.name)`