IOC Domain Internal Policy

// Copyright 2023 Google LLC. Licensed under Apache-2.0.

rule ioc_domain_internal_policy {

  meta:
    author = "Google Cloud Security"
    description = "Detect DNS events that communicate with gaming sites in MISP. These violate policy."
    rule_id = "mr_853bfafe-3049-43b5-a077-6a5f4a24ea3c"
    rule_name = "IOC Domain Internal Policy"
    type = "alert"
    tags = "threat indicators"
    assumption = "Assumes MISP data has been ingested into entity graph; this rule can be modified to utilize other TI indicators"
    data_source = "microsoft sysmon"
    severity = "Low"
    priority = "Low"

  events:
    $dns.metadata.event_type = "NETWORK_DNS"
    $dns.network.dns.questions.name = $dns_query

    // Correlates with MISP data; can be modified based on your MISP parser or other TI
    $ioc.graph.metadata.product_name = "MISP"
    $ioc.graph.metadata.entity_type = "DOMAIN_NAME"
    $ioc.graph.metadata.source_type = "ENTITY_CONTEXT"
    // Summary is used to focus on a specific subset of MISP indicators, can modify as needed
    $ioc.graph.metadata.threat.summary = "Gaming Sites"
    // Threat Feed Name is used to focus on a specific subset of MISP indicators, can modify as needed
    $ioc.graph.metadata.threat.threat_feed_name = "Internal"
    $ioc.graph.entity.hostname = $dns_query
    // Regex used to extract subset of data from field description, optional
    re.capture($ioc.graph.metadata.threat.description, "additional info: (.*)") = $info

  match:
    $dns_query over 5m

  outcome:
    $risk_score = 35
    $event_count = count_distinct($dns.metadata.id)
    // If not doing any additional extractions to $info placeholder variable, the following outcome variable can be removed
    $threat_info = array_distinct($info)
    $network_dns_questions_name = array_distinct($dns.network.dns.questions.name)
    $network_dns_answers_data = array_distinct($dns.network.dns.answers.data)
    // added to populate alert graph with additional context
    $principal_ip = array_distinct($dns.principal.ip)
    $target_ip = array_distinct($dns.target.ip)
    $principal_process_pid = array_distinct($dns.principal.process.pid)
    $principal_process_file_full_path = array_distinct($dns.principal.process.file.full_path)
    $principal_process_product_specific_process_id = array_distinct($dns.principal.process.product_specific_process_id)
    $principal_user_userid = array_distinct($dns.principal.user.userid)
    $principal_process_command_line = array_distinct($dns.principal.process.command_line)
    $principal_process_file_sha256 = array_distinct($dns.principal.process.file.sha256)
    $principal_process_parent_process_product_specific_process_id = array_distinct($dns.principal.process.parent_process.product_specific_process_id)

  condition:
    $dns and $ioc
}