sap system or client configuration change

/*
 * Copyright 2026 Google LLC
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     https://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

rule sap_system_or_client_configuration_change {
  meta:
    author = "Google Cloud Security"
    description = "Detects changes to either Global System Changeability (EU1) or Client-Specific Configuration (EU2/SCC4)."
    severity = "High"
    tactic = "TA0005"
    technique = "T1562.001"

  events:
    $e.metadata.log_type = "SAP_SECURITY_AUDIT"

        (
            $e.additional.fields["msg_1"] = "EU1" or
            $e.additional.fields["msg_1"] = "EU2"
        )


    $user = $e.principal.user.userid

  match:
    $user over 1h

  outcome:
    $risk_score = max(if($e.additional.fields["msg_1"] = "EU1", 95, 60))

    $client = array_distinct($e.target.resource.attribute.labels["slgmand"])
    $principal_user = array_distinct($user)
    $msg_id = array_distinct($e.additional.fields["msg_1"])
    $terminal_ip = array_distinct($e.principal.ip)
    $details = array_distinct($e.metadata.description)

  condition:
    $e
}