VT Relationships File Executes File

// Copyright 2023 Google LLC. Licensed under Apache-2.0.

rule vt_relationships_file_executes_file {

  meta:
    author = "Google Cloud Security"
    description = "Alert on known File Hash executing known File Hash with VT Relationships."
    rule_id = "mr_9250a0b5-b671-4c63-bb78-d7fda0ac2cf4"
    rule_name = "VT Relationships File Executes File"
    type = "alert"
    tags = "vt"
    data_source = "microsoft sysmon"
    severity = "High"
    priority = "High"

  events:
    $process.metadata.event_type = "PROCESS_LAUNCH"
    $process.principal.process.file.sha256 = $p_file_hash
    $process.target.process.file.sha256 = $t_file_hash
    $process.principal.hostname = $hostname

    // Uses VirusTotal integration via entity graph, this section maps to principal process file hash
    $vt.graph.metadata.entity_type = "FILE"
    $vt.graph.metadata.source_type = "GLOBAL_CONTEXT"
    $vt.graph.metadata.vendor_name = "VirusTotal"
    $vt.graph.metadata.product_name = "VirusTotal Relationships"
    $vt.graph.entity.file.sha256 = $p_file_hash

    // Uses VirusTotal integration via entity graph, this section maps the hash to a hash it executes
    $vt.graph.relations.entity_type = "FILE"
    $vt.graph.relations.relationship = "EXECUTES"
    $vt.graph.relations.entity.file.sha256 = $t_file_hash

  match:
    $hostname over 5m

  outcome:
    $risk_score = 85
    $event_count = count_distinct($process.metadata.id)
    //added to populate alert graph with additional context
    // Commented out principal.hostname because it is already represented in graph as match variable. If match changes, can uncomment to add to results
    //$principal_hostname = array_distinct($process.principal.hostname)
    $principal_process_pid = array_distinct($process.principal.process.pid)
    $principal_process_command_line = array_distinct($process.principal.process.command_line)
    $principal_process_file_sha256 = array_distinct($process.principal.process.file.sha256)
    $principal_process_file_full_path = array_distinct($process.principal.process.file.full_path)
    $principal_process_product_specific_process_id = array_distinct($process.principal.process.product_specific_process_id)
    $principal_process_parent_process_product_specific_process_id = array_distinct($process.principal.process.parent_process.product_specific_process_id)
    $target_process_pid = array_distinct($process.target.process.pid)
    $target_process_command_line = array_distinct($process.target.process.command_line)
    $target_process_file_sha256 = array_distinct($process.target.process.file.sha256)
    $target_process_file_full_path = array_distinct($process.target.process.file.full_path)
    $target_process_product_specific_process_id = array_distinct($process.target.process.product_specific_process_id)
    $principal_user_userid = array_distinct($process.principal.user.userid)

  condition:
    $process and $vt
}