Hunt Device Discovery Subnet Ranges

Group by: IPv4Dhcp, NetworkName
Author: Robbe Van den Daele
Source: github.com/HybridBrothers/Hunting-Queries-Detection-Rules

This KQL query helps you identify which subnet ranges are behind the Microsoft Defender for Endpoint Device Discovery 'Monitored Networks' page. By using this query you can investigate if all of your corporate networks are being monitored and change monitored states effectivly. More information can be found in the references.

References

https://hybridbrothers.com/mde-device-discovery-improving-the-monitored-network-page/

Telemetry coverage

Platform	Record / event type
Microsoft Defender for Endpoint	`DeviceNetworkInfo` action `any`: Device network configuration

Rule body

// OPTIONAL - Device cap used to ignore network with less then X devices in them
let device_cap = 0;
DeviceNetworkInfo
| where Timestamp > ago(7d)
// Ignore empty networks
| where ConnectedNetworks  != ""
// Get networks data
| extend ConnectedNetworksExp = parse_json(ConnectedNetworks)
| mv-expand bagexpansion = array ConnectedNetworks=ConnectedNetworksExp
| extend NetworkName = tostring(ConnectedNetworks ["Name"]), NetworkDescription = tostring(ConnectedNetworks ["Description"]), NetworkCategory = tostring(ConnectedNetworks ["Category"])
// Get subnet data for IPv4 Addresses
| extend IPAddressesExp = parse_json(IPAddresses)
| mv-expand bagexpansion = array IPAddresses=IPAddressesExp
| extend IPAddress = tostring(IPAddresses ["IPAddress"]), SubnetPrefix = tolong(IPAddresses ["SubnetPrefix"])
| extend NetworkAddress = format_ipv4(IPAddress, SubnetPrefix)
| extend SubnetRange = strcat(NetworkAddress, "/", SubnetPrefix)
// Exclude IPv6 and APIPPA
| where SubnetPrefix <= 32
| where IPAddress !startswith "169.254"
// Ignore unidentified networks
| where not(NetworkName has_any ("Unidentified", "Identifying..."))
// Provide list
| distinct DeviceId, NetworkName, IPv4Dhcp, SubnetRange
| summarize Devices = count(), SubnetRanges = make_set(SubnetRange) by NetworkName, IPv4Dhcp
// Ignore network with very low device count
| where Devices >= device_cap
| sort by Devices desc

// OPTIONAL - Device cap used to ignore network with less then X devices in them
let device_cap = 0;
DeviceNetworkInfo
| where TimeGenerated > ago(7d)
// Ignore empty networks
| where ConnectedNetworks  != ""
// Get networks data
| extend ConnectedNetworksExp = parse_json(ConnectedNetworks)
| mv-expand bagexpansion = array ConnectedNetworks=ConnectedNetworksExp
| extend NetworkName = tostring(ConnectedNetworks ["Name"]), NetworkDescription = tostring(ConnectedNetworks ["Description"]), NetworkCategory = tostring(ConnectedNetworks ["Category"])
// Get subnet data for IPv4 Addresses
| extend IPAddressesExp = parse_json(IPAddresses)
| mv-expand bagexpansion = array IPAddresses=IPAddressesExp
| extend IPAddress = tostring(IPAddresses ["IPAddress"]), SubnetPrefix = tolong(IPAddresses ["SubnetPrefix"])
| extend NetworkAddress = format_ipv4(IPAddress, SubnetPrefix)
| extend SubnetRange = strcat(NetworkAddress, "/", SubnetPrefix)
// Exclude IPv6 and APIPPA
| where SubnetPrefix <= 32
| where IPAddress !startswith "169.254"
// Ignore unidentified networks
| where not(NetworkName has_any ("Unidentified", "Identifying..."))
// Provide list
| distinct DeviceId, NetworkName, IPv4Dhcp, SubnetRange
| summarize Devices = count(), SubnetRanges = make_set(SubnetRange) by NetworkName, IPv4Dhcp
// Ignore network with very low device count
| where Devices >= device_cap
| sort by Devices desc

Stages and Predicates

Parameters

let device_cap = 0;

Stage 1: `source`

DeviceNetworkInfo

Stage 2: `where`

| where Timestamp > ago(7d)

Stage 3: `where`

| where ConnectedNetworks  != ""

Stage 4: `extend`

| extend ConnectedNetworksExp = parse_json(ConnectedNetworks)

Stage 5: `mv-expand`

| mv-expand bagexpansion = array ConnectedNetworks=ConnectedNetworksExp

Stage 6: `extend`

| extend NetworkName = tostring(ConnectedNetworks ["Name"]), NetworkDescription = tostring(ConnectedNetworks ["Description"]), NetworkCategory = tostring(ConnectedNetworks ["Category"])

Stage 7: `extend`

| extend IPAddressesExp = parse_json(IPAddresses)

Stage 8: `mv-expand`

| mv-expand bagexpansion = array IPAddresses=IPAddressesExp

Stage 9: `extend` (3 consecutive steps)

| extend IPAddress = tostring(IPAddresses ["IPAddress"]), SubnetPrefix = tolong(IPAddresses ["SubnetPrefix"])
| extend NetworkAddress = format_ipv4(IPAddress, SubnetPrefix)
| extend SubnetRange = strcat(NetworkAddress, "/", SubnetPrefix)

Stage 10: `where`

| where SubnetPrefix <= 32

Stage 11: `where`

| where IPAddress !startswith "169.254"

Stage 12: `where`

| where not(NetworkName has_any ("Unidentified", "Identifying..."))

Stage 13: `distinct`

| distinct DeviceId, NetworkName, IPv4Dhcp, SubnetRange

Stage 14: `summarize`

| summarize Devices = count(), SubnetRanges = make_set(SubnetRange) by NetworkName, IPv4Dhcp

Stage 15: `where`

| where Devices >= device_cap

Stage 16: `sort`

| sort by Devices desc

Exclusions

The rule actively suppresses these predicates.

Field	Kind	Excluded values	Search
`IPAddress`	starts_with	`169.254`	`excludes:IPAddress` `field:"IPAddress" value:"169.254"`
`NetworkName`	match	`Unidentified`, `Identifying...`	`excludes:NetworkName` `field:"NetworkName" value:"Unidentified"` `field:"NetworkName" value:"Identifying..."`

Indicators

These rows show field, operator, and value matches.

Field	Kind	Values	Search
`Devices`	ge	`0`	`field:"Devices" kind:ge value:"0"`
`SubnetPrefix`	le	`32`	`field:"SubnetPrefix" kind:le value:"32"`

Output fields

These fields are emitted when the rule matches.

Field	Source
`Devices`	`summarize`
`IPv4Dhcp`	`summarize`
`NetworkName`	`summarize`
`SubnetRanges`	`summarize`

Hunt Device Discovery Subnet Ranges

References

Telemetry coverage

Rule body

Stages and Predicates

Parameters

Stage 1: source

Stage 2: where

Stage 3: where

Stage 4: extend

Stage 5: mv-expand

Stage 6: extend

Stage 7: extend

Stage 8: mv-expand

Stage 9: extend (3 consecutive steps)

Stage 10: where

Stage 11: where

Stage 12: where

Stage 13: distinct

Stage 14: summarize

Stage 15: where

Stage 16: sort